# -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

# $Id$

# This file is part of waproamd.
#
# waproamd is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# waproamd is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with waproamd; if not, write to the Free Software Foundation,
# Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.

AC_PREREQ(2.57)
AC_INIT([waproamd], [0.1], [mzjncebnzq@itaparica.org])
AC_CONFIG_SRCDIR([src/waproamd.c])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([foreign -Wall])

# Checks for programs.
AC_PROG_CC
AC_PROG_LN_S
AC_PROG_MAKE_SET

# If using GCC specifiy some additional parameters
if test "x$GCC" = "xyes" ; then
   CFLAGS="$CFLAGS -pipe -Wall"
fi

if test -d /usr/local/stow ; then
   AC_MSG_NOTICE([*** Found /usr/local/stow: installing to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
   AC_PREFIX_DEFAULT([/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}])
fi

# Checks for libraries.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([fcntl.h limits.h stdint.h stdlib.h string.h sys/ioctl.h sys/socket.h unistd.h])

AC_CHECK_LIB([daemon], [daemon_fork],, [AC_MSG_ERROR([*** Sorry, you have to install libdaemon ***])])
AC_CHECK_LIB([mcrypt], [mcrypt_module_open], [MCRYPT=1 AC_DEFINE(HAVE_MCRYPT, 1, [libmcrypt available])], [MCRYPT=0])

AC_C_CONST
AC_TYPE_MODE_T
AC_TYPE_PID_T
AC_HEADER_TIME

AC_FUNC_FORK
AC_PROG_GCC_TRADITIONAL
AC_FUNC_MALLOC
AC_FUNC_MEMCMP
AC_FUNC_SELECT_ARGTYPES
AC_CHECK_FUNCS([dup2 ftruncate memset select setenv socket strchr strcspn strdup strerror strrchr])

# LYNX documentation generation
AC_ARG_ENABLE(lynx,
        AC_HELP_STRING([--disable-lynx], [Turn off lynx usage for documentation generation]),
[case "${enableval}" in
  yes) lynx=yes ;;
  no)  lynx=no ;;
  *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
esac],[lynx=yes])

if test x$lynx = xyes ; then
   AC_CHECK_PROG(have_lynx, lynx, yes, no)

   if test x$have_lynx = xno ; then
     AC_MSG_ERROR([*** Sorry, you have to install lynx or use --disable-lynx ***])
   fi
fi

AM_CONDITIONAL([USE_LYNX], [test "x$lynx" = xyes])

# XMLTOMAN manpage generation
AC_ARG_ENABLE(xmltoman,
        AC_HELP_STRING([--disable-xmltoman], [Disable rebuilding of man pages with xmltoman]),
[case "${enableval}" in
  yes) xmltoman=yes ;;
  no)  xmltoman=no ;;
  *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
esac],[xmltoman=yes])

if test x$xmltoman = xyes ; then
   AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)

   if test x$have_xmltoman = xno ; then
     AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
     xmltoman=no
   fi
fi

AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])

# Build aeswepd?
AC_ARG_ENABLE(aeswepd,
        AC_HELP_STRING([--disable-aeswepd], [Disable building of aeswepd]),
[case "${enableval}" in
  yes) aeswepd=yes ;;
  no)  aeswepd=no ;;
  *) AC_MSG_ERROR([bad value ${enableval} for --disable-aeswepd]) ;;
esac], [aeswepd=yes])

# Build waproamd?
AC_ARG_ENABLE(waproamd,
        AC_HELP_STRING([--disable-waproamd], [Disable building of waproamd]),
[case "${enableval}" in
  yes) waproamd=yes ;;
  no)  waproamd=no ;;
  *) AC_MSG_ERROR([bad value ${enableval} for --disable-waproamd]) ;;
esac], [waproamd=yes])

if test x$aeswepd = xno && test x$waproamd = xno ; then
   AC_MSG_ERROR([*** If you build neither aeswepd nor waproamd, nothing gets built ***])
fi

if test x$aeswepd = xyes && test x$MCRYPT != x1 ; then
   AC_MSG_ERROR([*** Sorry, you have to install libmcrypt or use --disable-aeswepd ***])
fi

AM_CONDITIONAL([BUILD_AESWEPD], [test "x$aeswepd" = xyes])
AM_CONDITIONAL([BUILD_WAPROAMD], [test "x$waproamd" = xyes])

AC_CONFIG_FILES([src/Makefile Makefile conf/Makefile doc/Makefile]) # man/Makefile doc/Makefile doc/README.html])
AC_OUTPUT

AC_MSG_NOTICE([*** aeswepd is built: $aeswepd ***])
AC_MSG_NOTICE([*** waproamd is built: $waproamd ***])