# -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

# This file is part of libsydney.
#
# Copyright 2007-2008 Lennart Poettering
#
# libsydney is free software; you can redistribute it and/or modify it
# under the terms of the GNU Lesser General Public License as
# published by the Free Software Foundation, either version 2.1 of the
# License, or (at your option) any later version.
#
# libsydney is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with libsydney. If not, see
# <http://www.gnu.org/licenses/>.

AC_PREREQ(2.62)

AC_INIT([libsydney], 0.1, [mzyvoflqarl (at) 0pointer (dot) de])
AC_CONFIG_SRCDIR([src/common.c])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_MACRO_DIR(m4)
AM_INIT_AUTOMAKE([foreign 1.9 -Wall])

AC_SUBST(PACKAGE_URL, [https://tango.0pointer.de/mailman/listinfo/libsydney-discuss/])

AC_SUBST(LIBSYDNEY_VERSION_INFO, [0:0:0])

AC_CANONICAL_HOST

if type -p stow > /dev/null && test -d /usr/local/stow ; then
   AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
   ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
fi

#### Checks for programs. ####

# CC

AC_PROG_CC
AC_PROG_CC_C99
AM_PROG_CC_C_O
AC_PROG_GCC_TRADITIONAL
AC_GNU_SOURCE

# C++

AC_PROG_CXX

DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wconversion -Wundef -Wformat -Wlogical-op -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"

for flag in $DESIRED_FLAGS ; do
  CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
done

#### libtool stuff ####

AC_LTDL_ENABLE_INSTALL
AC_LIBLTDL_INSTALLABLE
AC_LIBTOOL_DLOPEN
AC_LIBTOOL_WIN32_DLL
AC_PROG_LIBTOOL
AC_SUBST(LTDLINCL)
AC_SUBST(LIBLTDL)
AC_CONFIG_SUBDIRS(libltdl)

#### Determine build environment ####

os_is_win32=0

case "$host_os" in
     mingw*)
        AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
        os_is_win32=1
     ;;
esac

AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")

AM_CONDITIONAL(USE_VERSION_SCRIPT, test "x$supports_anon_versioning" = "xyes" )

###################################
#   Basic environment checks      #
###################################

#### Checks for header files. ####

# ISO
AC_HEADER_STDC

# XPG4-UNIX
AC_CHECK_HEADERS([sys/poll.h])

# Other
AC_CHECK_HEADERS([sys/ioctl.h])
AC_CHECK_HEADERS([byteswap.h])

#### Typdefs, structures, etc. ####

AC_C_CONST
AC_C_BIGENDIAN
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
    [Define ssize_t if it is not done by the standard libs.])])
AC_TYPE_OFF_T
AC_TYPE_SIGNAL
AC_TYPE_UID_T

#### Check for libs ####

# ISO
AC_SEARCH_LIBS([pow], [m])

# POSIX
AC_SEARCH_LIBS([sched_setscheduler], [rt])

# Non-standard

#### Check for functions ####

# ISO
AC_CHECK_FUNCS([lrintf strtof])

# POSIX
AC_FUNC_SELECT_ARGTYPES
AC_CHECK_FUNCS([gettimeofday nanosleep posix_memalign sigaction sleep sysconf pthread_yield])

# SUSv3
AC_CHECK_FUNCS([strerror_r])

# BSD
AC_CHECK_FUNCS([lstat])

# GNU
AC_CHECK_FUNCS([strndup])

#### POSIX threads ####

ACX_PTHREAD

AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
AC_LANG_CONFTEST([AC_LANG_SOURCE([[
#include <pthread.h>
int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
$PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
ret=$?
rm -f conftest.o conftest

if test $ret -eq 0 ; then
    AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
    AC_MSG_RESULT([yes])
else
    AC_MSG_RESULT([no])
fi

#### Large File-Support (LFS) ####

AC_SYS_LARGEFILE

# Check for open64 to know if the current system does have open64() and similar functions
AC_CHECK_FUNCS([open64])

#### [lib]iconv ####

AM_ICONV

###################################
#      External libraries         #
###################################

#### pkg-config ####

# Check for pkg-config manually first, as if its not installed the
# PKG_PROG_PKG_CONFIG macro won't be defined.
AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)

if test x"$have_pkg_config" = "xno"; then
    AC_MSG_ERROR(pkg-config is required to install this program)
fi

PKG_PROG_PKG_CONFIG

### OSS support (optional) ###

AC_ARG_ENABLE([oss],
    AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
        [
            case "${enableval}" in
                yes) oss=yes ;;
                no) oss=no ;;
                *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
            esac
        ],
        [oss=auto])

if test "x${oss}" != xno ; then
    AC_CHECK_HEADERS(soundcard.h sys/soundcard.h machine/soundcard.h)
    if test "${ac_cv_header_sys_soundcard_h}" = "yes" || \
	test "${ac_cv_header_soundcard_h}" = "yes" || \
	test "${ac_cv_header_machine_soundcard_h}" = "yes"; then
	HAVE_OSS=1
        AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
    else
	HAVE_OSS=0
        if test "x$oss" = xyes ; then
            AC_MSG_ERROR([*** OSS not found ***])
        fi
    fi
else
    HAVE_OSS=0
fi

#### ALSA support (optional) ####

AC_ARG_ENABLE([alsa],
    AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
        [
            case "${enableval}" in
                yes) alsa=yes ;;
                no) alsa=no ;;
                *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
            esac
        ],
        [alsa=auto])

if test "x${alsa}" != xno ; then
    PKG_CHECK_MODULES(ALSA, [ alsa >= 1.0.0 ],
        [
            HAVE_ALSA=1
            AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
        ],
        [
            HAVE_ALSA=0
            if test "x$alsa" = xyes ; then
                AC_MSG_ERROR([*** ALSA support not found])
            fi
        ])
else
    HAVE_ALSA=0
fi

AC_SUBST(ALSA_CFLAGS)
AC_SUBST(ALSA_LIBS)

### PulseAudio (optional) ####

AC_ARG_ENABLE([pulse],
    AC_HELP_STRING([--disable-pulse], [Disable optional PulseAudio support]),
        [
            case "${enableval}" in
                yes) pulse=yes ;;
                no) pulse=no ;;
                *) AC_MSG_ERROR(bad value ${enableval} for --disable-pulse) ;;
            esac
        ],
        [pulse=auto])

if test "x${pulse}" != xno ; then

    if test -d ../pulseaudio ; then
        PULSE_CFLAGS='-I$(top_srcdir)/../pulseaudio/src'
        PULSE_LIBS='-L$(top_srcdir)/../pulseaudio/src/.libs -lpulse'
        HAVE_PULSE=1
        AC_DEFINE([HAVE_PULSE], 1, [Have PulseAudio?])
        echo "*** Found pulseaudio in ../pulseaudio, using that version ***"
    else
        PKG_CHECK_MODULES(PULSE, [ libpulse >= 0.9.11 ],
        [
            HAVE_PULSE=1
            AC_DEFINE([HAVE_PULSE], 1, [Have PulseAudio?])
        ],
        [
            HAVE_PULSE=0
            if test "x$pulse" = xyes ; then
                AC_MSG_ERROR([*** PulseAudio not found ***])
            fi
        ])
    fi
else
    HAVE_PULSE=0
fi

AC_SUBST(PULSE_CFLAGS)
AC_SUBST(PULSE_LIBS)

### JACK (optional) ####

AC_ARG_ENABLE([jack],
    AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
        [
            case "${enableval}" in
                yes) jack=yes ;;
                no) jack=no ;;
                *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
            esac
        ],
        [jack=auto])

if test "x${jack}" != xno ; then
    PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
        HAVE_JACK=1,
        [
            HAVE_JACK=0
            if test "x$jack" = xyes ; then
                AC_MSG_ERROR([*** JACK support not found])
            fi
        ])
else
    HAVE_JACK=0
fi

AC_SUBST(JACK_CFLAGS)
AC_SUBST(JACK_LIBS)

### Null output (optional) ####

AC_ARG_ENABLE([null],
    AC_HELP_STRING([--disable-null], [Disable optional null output]),
        [
            case "${enableval}" in
                yes) null=yes ;;
                no) null=no ;;
                *) AC_MSG_ERROR(bad value ${enableval} for --disable-null) ;;
            esac
        ],
        [null=yes])

if test "x${null}" != xno ; then
    HAVE_NULL=1
    AC_DEFINE([HAVE_NULL], 1, [Have NULL output?])
else
    HAVE_NULL=0
fi

### liboil (mandatory) ####

PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
AC_SUBST(LIBOIL_CFLAGS)
AC_SUBST(LIBOIL_LIBS)

### libspeex (mandatory) ####

PKG_CHECK_MODULES(SPEEX, [ speexdsp >= 1.2 ])
AC_SUBST(SPEEX_CFLAGS)
AC_SUBST(SPEEX_LIBS)

### Chose builtin driver ###

AC_ARG_WITH([builtin],
            [AS_HELP_STRING([--with-builtin], [Choose builtin driver])],
            [],
            [with_builtin=dso])

HAVE_DSO=0
BUILTIN_DSO=0
BUILTIN_PULSE=0
BUILTIN_ALSA=0
BUILTIN_OSS=0
BUILTIN_JACK=0
BUILTIN_NULL=0

case "x$with_builtin" in
     xpulse)
        if test "x$HAVE_PULSE" != x1 ; then
                AC_MSG_ERROR([*** PulseAudio selected for builtin driver, but not enabled. ***])
        fi

        BUILTIN_PULSE=1
        HAVE_ALSA=0
        HAVE_OSS=0
        HAVE_JACK=0
        HAVE_NULL=0
     ;;

     xalsa)
        if test "x$HAVE_ALSA" != x1 ; then
                AC_MSG_ERROR([*** ALSA selected for builtin driver, but not enabled. ***])
        fi

        BUILTIN_ALSA=1
        HAVE_OSS=0
        HAVE_PULSE=0
        HAVE_JACK=0
        HAVE_NULL=0
     ;;

     xoss)
        if test "x$HAVE_OSS" != x1 ; then
                AC_MSG_ERROR([*** OSS selected for builtin driver, but not enabled. ***])
        fi

        BUILTIN_OSS=1
        HAVE_ALSA=0
        HAVE_PULSE=0
        HAVE_JACK=0
        HAVE_NULL=0
     ;;

     xjack)
        if test "x$HAVE_JACK" != x1 ; then
                AC_MSG_ERROR([*** JACK selected for builtin driver, but not enabled. ***])
        fi

        BUILTIN_JACK=1
        HAVE_ALSA=0
        HAVE_PULSE=0
        HAVE_JACK=0
        HAVE_NULL=0
     ;;

     xnull)
        if test "x$HAVE_NULL" != x1 ; then
                AC_MSG_ERROR([*** Null output selected for builtin driver, but not enabled. ***])
        fi

        BUILTIN_NULL=1
        HAVE_PULSE=0
        HAVE_ALSA=0
        HAVE_OSS=0
        HAVE_JACK=0
     ;;

     xdso)
        BUILTIN_DSO=1
        HAVE_DSO=1
        AC_DEFINE([HAVE_DSO], 1, [Have DSO?])
     ;;

     *)
        AC_MSG_ERROR([*** Unknown driver $with_builtin selected for builtin ***])
esac

if test "x$HAVE_PULSE" != x1 -a "x$HAVE_ALSA" != x1 -a "x$HAVE_OSS" != x1 -a "x$HAVE_JACK" != x1 -a "x$HAVE_NULL" != x1 ; then
   AC_MSG_ERROR([*** No backend enabled. ***])
fi

AC_SUBST(HAVE_DSO)
AC_SUBST(HAVE_PULSE)
AC_SUBST(HAVE_ALSA)
AC_SUBST(HAVE_OSS)
AC_SUBST(HAVE_JACK)
AC_SUBST(HAVE_NULL)
AC_SUBST(BUILTIN_DSO)
AC_SUBST(BUILTIN_PULSE)
AC_SUBST(BUILTIN_ALSA)
AC_SUBST(BUILTIN_OSS)
AC_SUBST(BUILTIN_JACK)
AC_SUBST(BUILTIN_NULL)
AM_CONDITIONAL([HAVE_PULSE], [test "x$HAVE_PULSE" = x1])
AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
AM_CONDITIONAL([HAVE_NULL], [test "x$HAVE_NULL" = x1])
AM_CONDITIONAL([BUILTIN_DSO], [test "x$BUILTIN_DSO" = x1])
AM_CONDITIONAL([BUILTIN_PULSE], [test "x$BUILTIN_PULSE" = x1])
AM_CONDITIONAL([BUILTIN_ALSA], [test "x$BUILTIN_ALSA" = x1])
AM_CONDITIONAL([BUILTIN_OSS], [test "x$BUILTIN_OSS" = x1])
AM_CONDITIONAL([BUILTIN_JACK], [test "x$BUILTIN_JACK" = x1])
AM_CONDITIONAL([BUILTIN_NULL], [test "x$BUILTIN_NULL" = x1])

GTK_DOC_CHECK(1.9)

###################################
#            Output               #
###################################

AC_CONFIG_FILES([
Makefile
src/Makefile
libsydney.pc
])
AC_OUTPUT

# ==========================================================================
ENABLE_BUILTIN_DSO=no
if test "x$BUILTIN_DSO" = "x1" ; then
   ENABLE_BUILTIN_DSO=yes
fi

ENABLE_PULSE=no
if test "x$HAVE_PULSE" = "x1" ; then
   ENABLE_PULSE=yes
fi
ENABLE_BUILTIN_PULSE=no
if test "x$BUILTIN_PULSE" = "x1" ; then
   ENABLE_BUILTIN_PULSE=yes
fi

ENABLE_ALSA=no
if test "x$HAVE_ALSA" = "x1" ; then
   ENABLE_ALSA=yes
fi
ENABLE_BUILTIN_ALSA=no
if test "x$BUILTIN_ALSA" = "x1" ; then
   ENABLE_BUILTIN_ALSA=yes
fi

ENABLE_OSS=no
if test "x$HAVE_OSS" = "x1" ; then
    ENABLE_OSS=yes
fi
ENABLE_BUILTIN_OSS=no
if test "x$BUILTIN_OSS" = "x1" ; then
    ENABLE_BUILTIN_OSS=yes
fi

ENABLE_JACK=no
if test "x$HAVE_JACK" = "x1" ; then
   ENABLE_JACK=yes
fi
ENABLE_BUILTIN_JACK=no
if test "x$BUILTIN_JACK" = "x1" ; then
   ENABLE_BUILTIN_JACK=yes
fi

ENABLE_NULL=no
if test "x$HAVE_NULL" = "x1" ; then
   ENABLE_NULL=yes
fi
ENABLE_BUILTIN_NULL=no
if test "x$BUILTIN_NULL" = "x1" ; then
   ENABLE_BUILTIN_NULL=yes
fi

echo "
 ---{ $PACKAGE_NAME $VERSION }---

    prefix:                 ${prefix}
    sysconfdir:             ${sysconfdir}
    localstatedir:          ${localstatedir}
    Compiler:               ${CC}
    CFLAGS:                 ${CFLAGS}
    C++-Compiler:           ${CXX}
    CXXFLAGS:               ${CXXFLAGS}
    Builtin DSO:            ${ENABLE_BUILTIN_DSO}
    Enable PulseAudio:      ${ENABLE_PULSE}
    Builtin PulseAudio:     ${ENABLE_BUILTIN_PULSE}
    Enable ALSA:            ${ENABLE_ALSA}
    Builtin ALSA:           ${ENABLE_BUILTIN_ALSA}
    Enable OSS:             ${ENABLE_OSS}
    Builtin OSS:            ${ENABLE_BUILTIN_OSS}
    Enable Jack:            ${ENABLE_JACK}
    Builtin Jack:           ${ENABLE_BUILTIN_JACK}
    Enable Null Output:     ${ENABLE_NULL}
    Builtin Null Output:    ${ENABLE_BUILTIN_NULL}
"