From 637ed0af936a25d2633110963ad6ec333859fa28 Mon Sep 17 00:00:00 2001
From: Lennart Poettering <lennart@poettering.net>
Date: Wed, 21 Jun 2006 11:05:28 +0000
Subject: add proper autoconfization

git-svn-id: file:///home/lennart/svn/public/padevchooser/trunk@8 e4aeda27-4315-0410-ac56-b21855d76123
---
 configure.ac | 83 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 83 insertions(+)
 create mode 100644 configure.ac

(limited to 'configure.ac')

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..9d2f041
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,83 @@
+# -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
+
+# $Id$
+
+# This file is part of padevchooser.
+#
+# padevchooser is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# padevchooser is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with padevchooser; if not, write to the Free Software Foundation,
+# Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
+
+AC_PREREQ(2.57)
+AC_INIT([padevchooser],[0.9.2],[mzcnqripubbfre (at) 0pointer (dot) de])
+AC_CONFIG_SRCDIR([src/padevchooser.c])
+AC_CONFIG_HEADERS([config.h])
+AM_INIT_AUTOMAKE([foreign 1.9 -Wall])
+
+AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/padevchooser/])
+
+if type -p stow > /dev/null && test -d /usr/local/stow ; then
+   AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
+   ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
+fi
+
+# Checks for programs.
+AC_PROG_CXX
+AC_PROG_CC
+AC_PROG_LN_S
+AC_TYPE_SIGNAL
+AC_HEADER_STDC
+
+PKG_CHECK_MODULES(GUILIBS, [ gtk+-2.0 libnotify libglade-2.0 gconf-2.0 ])
+AC_SUBST(GUILIBS_CFLAGS)
+AC_SUBST(GUILIBS_LIBS)
+
+if test -d ../pulseaudio ; then
+   PULSE_CFLAGS='-I$(top_srcdir)/../pulseaudio/src'
+   PULSE_LIBS='-L$(top_srcdir)/../pulseaudio/src/.libs -lpulse -lpulse-mainloop-glib -lpulse-browse'
+   echo "*** Found pulseaudio in ../pulseaudio, using that version ***"
+else
+   PKG_CHECK_MODULES(PULSE, [ libpulse >= 0.9.2 libpulse-browser >= 0.9.2 libpulse-mainloop-glib >= 0.9.2 ])
+fi
+
+AC_SUBST(PULSE_LIBS)
+AC_SUBST(PULSE_CFLAGS)
+
+# If using GCC specifiy some additional parameters
+if test "x$GCC" = "xyes" ; then
+   CFLAGS="$CFLAGS -pipe -Wall -W -Wno-unused-parameter"
+   CXXFLAGS="$CXXFLAGS -pipe -Wall -W"
+fi
+
+# LYNX documentation generation
+AC_ARG_ENABLE(lynx,
+        AS_HELP_STRING(--disable-lynx,Turn off lynx usage for documentation generation),
+[case "${enableval}" in
+  yes) lynx=yes ;;
+  no)  lynx=no ;;
+  *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
+esac],[lynx=yes])
+
+if test x$lynx = xyes ; then
+   AC_CHECK_PROG(have_lynx, lynx, yes, no)
+
+   if test x$have_lynx = xno ; then
+     AC_MSG_ERROR([*** Sorry, you have to install lynx or use --disable-lynx ***])
+   fi
+fi
+
+AM_CONDITIONAL([USE_LYNX], [test "x$lynx" = xyes])
+
+AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile doc/README.html])
+AC_OUTPUT
-- 
cgit