AC_INIT([udev-extras],
	[20090509],
	[linux-hotplug@vger.kernel.org])
AC_PREREQ(2.60)
AM_INIT_AUTOMAKE([check-news foreign 1.9 subdir-objects dist-bzip2])
AC_USE_SYSTEM_EXTENSIONS
AC_SYS_LARGEFILE
AC_CONFIG_MACRO_DIR([m4])

dnl prefix is /usr, exec_prefix in /, if overridden exec_prefix follows prefix
AC_PREFIX_DEFAULT([/usr])
test "$prefix" = NONE && test "$exec_prefix" = NONE && exec_prefix=

PKG_CHECK_MODULES(LIBUSB, libusb >= 0.1.12)
AC_SUBST(LIBUSB_CFLAGS)
AC_SUBST(LIBUSB_LIBS)

PKG_CHECK_MODULES(LIBUDEV, libudev >= 141)
AC_SUBST(LIBUDEV_CFLAGS)
AC_SUBST(LIBUDEV_LIBS)

PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])

AC_PATH_PROG([XSLTPROC], [xsltproc])
AC_PROG_AWK
AC_PATH_PROG([GPERF], [gperf])
if test -z "$GPERF"; then
    AC_MSG_ERROR(Could not find gperf)
fi

AC_ARG_WITH(udev-prefix,
	AS_HELP_STRING([--with-udev-prefix=DIR], [add prefix to internal udev path names]),
	[], [with_udev_prefix='${exec_prefix}'])
udev_prefix=$with_udev_prefix
AC_SUBST(udev_prefix)

AC_DEFINE(LIBUDEV_I_KNOW_THE_API_IS_SUBJECT_TO_CHANGE, 1, [I know the API is subject to change])

AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
AC_ARG_WITH(pci-ids-path,
	AS_HELP_STRING([--pci-ids-path=DIR], [Path to pci.ids file]),
	[PCI_DATABASE=${withval}],
	[if test -n "$pciids" ; then
		PCI_DATABASE="$pciids"
	else
		AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
	fi])
AC_SUBST(PCI_DATABASE)

AC_CONFIG_HEADERS(config.h)
AC_CONFIG_FILES([
Makefile
rules.d/Makefile
modem-modeswitch/Makefile
udev-acl/Makefile
keymap/Makefile
v4l_id/Makefile
usb-db/Makefile
])

AC_OUTPUT
AC_MSG_RESULT([
	udev-extras $VERSION
	====================

	prefix:			${prefix}
	exec_prefix:		${exec_prefix}
	udev_prefix:		${udev_prefix}
	datarootdir:		${datarootdir}
	mandir:			${mandir}

	usb.ids:		${USB_DATABASE}
	pci.ids:		${PCI_DATABASE}

	compiler:		${CC}
	cflags:			${CFLAGS}
	ldflags:		${LDFLAGS}

	xsltproc:		${XSLTPROC}
	gperf:			${GPERF}
])