/* --*-c-mode-*-- */

%{

#include <stdio.h>

    
%}

%Start DEF CCOMMENT CPPCOMMENT STRING CHAR PREPROC

IDCHAR [_a-zA-Z0-9]
NIDCHAR [^_a-zA-Z0-9]

%%

 BEGIN DEF;

<DEF>^#ifn?def |
<DEF>^#if      |
<DEF>^#define  |
<DEF>^#undef   ;

<DEF>^#. { BEGIN CPPCOMMENT; }

<DEF>"/*" { BEGIN CCOMMENT; }
<CCOMMENT>"*/" { BEGIN DEF; }
<CCOMMENT>\n |
<CCOMMENT>. ;

<DEF>"//" { BEGIN CPPCOMMENT; }
<CPPCOMMENT>\n { BEGIN DEF; }
<CPPCOMMENT>. ;

<DEF>"\"" { BEGIN STRING; }
<STRING>"\"" { BEGIN DEF; }
<STRING>. |
<STRING>\n ;

<DEF>"'" { BEGIN CHAR; }
<CHAR>"'" { BEGIN DEF; }
<CHAR>\n |
<CHAR>. ;

<DEF>auto{NIDCHAR}  |
<DEF>break{NIDCHAR}  |
<DEF>case{NIDCHAR}  |
<DEF>char{NIDCHAR}  |
<DEF>const{NIDCHAR}  |
<DEF>continue{NIDCHAR}  |
<DEF>default{NIDCHAR}  |
<DEF>do{NIDCHAR}  |
<DEF>double{NIDCHAR}  |
<DEF>else{NIDCHAR}  |
<DEF>enum{NIDCHAR}  |
<DEF>extern{NIDCHAR}  |
<DEF>float{NIDCHAR}  |
<DEF>for{NIDCHAR}  |
<DEF>goto{NIDCHAR}  |
<DEF>if{NIDCHAR}  |
<DEF>int{NIDCHAR}  |
<DEF>long{NIDCHAR}  |
<DEF>register{NIDCHAR}  |
<DEF>return{NIDCHAR}  |
<DEF>short{NIDCHAR}  |
<DEF>signed{NIDCHAR}  |
<DEF>sizeof{NIDCHAR}  |
<DEF>static{NIDCHAR}  |
<DEF>struct{NIDCHAR}  |
<DEF>switch{NIDCHAR}  |
<DEF>typedef{NIDCHAR}  |
<DEF>union{NIDCHAR}  |
<DEF>unsigned{NIDCHAR}  |
<DEF>void{NIDCHAR}  |
<DEF>volatile{NIDCHAR}  |
<DEF>while{NIDCHAR} { yyless(yyleng-1);  }

<DEF>[a-zA-Z_][a-zA-Z_0-9]{3,} { printf("%s\n", yytext); }

<DEF>"\n" |
<DEF>. ;

%%

int main(int argc, char *argv[]) {

    if (argc <= 1)
        yylex();
    else {
        int i;
        
        for (i = 1; i < argc; i++) {
            if (!(freopen(argv[i], "r", stdin))) {
                fprintf(stderr, "Failed to open file: %s\n", strerror(errno));
                return 1;
            }
            yylex();
        }
    }

    return 0;
}