1 files changed, 162 insertions, 0 deletions
diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..88f058f
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,162 @@
+# -*- Autoconf -*-
+# Process this file with autoconf to produce a configure script.
+
+# $Id: configure.ac 13 2003-08-23 20:33:12Z lennart $
+
+# This file is part of syrep.
+#
+# syrep is free software; you can redistribute it and/or modify it
+# under the terms of the GNU General Public License as published by
+# the Free Software Foundation; either version 2 of the License, or
+# (at your option) any later version.
+#
+# syrep is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with syrep; if not, write to the Free Software Foundation,
+# Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
+
+AC_PREREQ(2.57)
+AC_INIT([syrep], [0.1], [mzflerc (at) 0pointer (dot) de])
+AC_CONFIG_SRCDIR([src/syrep.c])
+AC_CONFIG_HEADERS([config.h])
+AM_INIT_AUTOMAKE([foreign -Wall])
+
+# Checks for programs.
+AC_PROG_CC
+AC_PROG_LN_S
+
+AC_SUBST(PACKAGE_URL, [http://0pointer.de/lennart/projects/syrep/])
+
+if test -d /usr/local/stow ; then
+   AC_MSG_NOTICE([*** Found /usr/local/stow: installing to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
+   AC_PREFIX_DEFAULT([/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}])
+fi
+
+AC_CHECK_LIB([z], [inflate],, [AC_MSG_ERROR([*** Sorry, you have to install zlib ***])])
+AC_CHECK_HEADER([zlib.h],, [AC_MSG_ERROR([*** Sorry, you have to install the zlib headers ***])])
+
+AC_CHECK_HEADER([db.h],, [AC_MSG_ERROR([*** Sorry, you have to install the Berkeley Database Library (libdb) 4.1 or newer ***])])
+      
+LIBS="$LIBS -ldb"
+
+# If using GCC specify some additional parameters
+if test "x$GCC" = "xyes" ; then
+   CFLAGS="$CFLAGS -pipe -Wall"
+fi
+
+AC_C_BIGENDIAN
+
+if test "x$ac_cv_c_bigendian" = "xyes"; then
+   CFLAGS="$CPPFLAGS  -DARCH_IS_BIG_ENDIAN=1"
+else
+   CPPFLAGS="$CPPFLAGS -DARCH_IS_BIG_ENDIAN=0"
+fi
+
+# 64 Bit LFS support
+CPPFLAGS="$CPPFLAGS -D_FILE_OFFSET_BITS=64"
+
+AC_HEADER_DIRENT
+AC_HEADER_STDC
+AC_CHECK_HEADERS([fcntl.h inttypes.h limits.h malloc.h stdlib.h string.h unistd.h])
+
+# Checks for header files.
+AC_C_CONST
+AC_TYPE_MODE_T
+AC_TYPE_OFF_T
+AC_TYPE_SIZE_T
+AC_C_VOLATILE
+
+# Checks for library functions.
+AC_FUNC_CLOSEDIR_VOID
+AC_FUNC_MALLOC
+AC_FUNC_MEMCMP
+AC_FUNC_MMAP
+AC_FUNC_STAT
+AC_CHECK_FUNCS([atexit ftruncate getcwd gethostname memset mkdir munmap rmdir setenv strchr strdup strerror strrchr strtol])
+
+# LYNX documentation generation
+AC_ARG_ENABLE(lynx,
+        AC_HELP_STRING([--disable-lynx], [Turn off lynx usage for documentation generation]),
+[case "${enableval}" in
+  yes) lynx=yes ;;
+  no)  lynx=no ;;
+  *) AC_MSG_ERROR(bad value ${enableval} for --disable-lynx) ;;
+esac],[lynx=yes])
+
+if test x$lynx = xyes ; then
+   AC_CHECK_PROG(have_lynx, lynx, yes, no)
+
+   if test x$have_lynx = xno ; then
+     AC_MSG_ERROR([*** Sorry, you have to install lynx or use --disable-lynx ***])
+   fi
+fi
+
+AM_CONDITIONAL([USE_LYNX], [test "x$lynx" = xyes])
+
+# XMLTOMAN manpage generation
+AC_ARG_ENABLE(xmltoman,
+        AC_HELP_STRING([--disable-xmltoman], [Disable rebuilding of man pages with xmltoman]),
+[case "${enableval}" in
+  yes) xmltoman=yes ;;
+  no)  xmltoman=no ;;
+  *) AC_MSG_ERROR([bad value ${enableval} for --disable-xmltoman]) ;;
+esac],[xmltoman=yes])
+
+if test x$xmltoman = xyes ; then
+   AC_CHECK_PROG(have_xmltoman, xmltoman, yes, no)
+
+   if test x$have_xmltoman = xno ; then
+     AC_MSG_WARN([*** Not rebuilding man pages as xmltoman is not found ***])
+     xmltoman=no
+   fi
+fi
+
+AM_CONDITIONAL([USE_XMLTOMAN], [test "x$xmltoman" = xyes])
+
+# gengetopt command line parser generation
+AC_ARG_ENABLE(gengetopt,
+        AC_HELP_STRING([--disable-gengetopt], [Disable rebuilding of command line parser with gengetopt]),
+[case "${enableval}" in
+  yes) gengetopt=yes ;;
+  no)  gengetopt=no ;;
+  *) AC_MSG_ERROR([bad value ${enableval} for --disable-gengetopt]) ;;
+esac],[gengetopt=yes])
+
+if test x$gengetopt = xyes ; then
+   AC_CHECK_PROG(have_gengetopt, gengetopt, yes, no)
+
+   if test x$have_gengetopt = xno ; then
+     AC_MSG_WARN([*** Not rebuilding command line parser as gengetopt is not found ***])
+     gengetopt=no
+   fi
+fi
+
+AM_CONDITIONAL([USE_GENGETOPT], [test "x$gengetopt" = xyes])
+
+# subversion release number generation
+AC_ARG_ENABLE(subversion,
+        AC_HELP_STRING([--disable-subversion], [Disable rebuilding of svn-release.h]),
+[case "${enableval}" in
+  yes) subversion=yes ;;
+  no)  subversion=no ;;
+  *) AC_MSG_ERROR([bad value ${enableval} for --disable-subversion]) ;;
+esac],[subversion=yes])
+
+if test x$subversion = xyes ; then
+   AC_CHECK_PROG(have_subversion, svn, yes, no)
+
+   if test x$have_subversion = xno ; then
+     AC_MSG_WARN([*** Not rebuilding svn-release.h as subversion is not found ***])
+     subversion=no
+   fi
+fi
+
+AM_CONDITIONAL([USE_SUBVERSION], [test "x$subversion" = xyes])
+
+
+AC_CONFIG_FILES([src/Makefile Makefile doc/Makefile])  # man/Makefile doc/Makefile doc/README.html
+AC_OUTPUT